What is the probability with ten throws of the dice, that a six will come up exactly twice? The probability of a six (or any other number) is 1/6. The following formula combines these factors:

=B(10;1/6;2) returns a probability of 29%.

BETA.DIST

Returns the beta function.

Syntax

BETA.DIST(Number; Alpha; Beta; Cumulative [; Start [; End]])

Number (required) is the value between Start and End at which to evaluate the function.

Alpha (required) is a parameter to the distribution.

Beta (required) is a parameter to the distribution.

Cumulative (required) can be 0 or False to calculate the probability density function. It can be any other value or True to calculate the cumulative distribution function.

Start (optional) is the lower bound for Number.

End (optional) is the upper bound for Number.

In the Office Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

Example

=BETA.DIST(2;8;10;1;1;3) returns the value 0.6854706

=BETA.DIST(2;8;10;0;1;3) returns the value 1.4837646

Technical information

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.BETA.DIST

BETA.INV

Returns the inverse of the cumulative Beta probability density function.

Syntax

BETA.INV(Number; Alpha; Beta [; Start [; End]])

Number is the probability associated with the Beta distribution for the given arguments Alpha and Beta.

Alpha is a strictly positive parameter of the Beta distribution.

Beta is a strictly positive parameter of the Beta distribution.

Start (optional) is the lower bound of the output range of the function. If omitted, the default value is 0.

End (optional) is the upper bound of the output range of the function. If omitted, the default value is 1.

Example

=BETA.INV(0.5;5;10) returns the value 0.3257511553.

BETA.INV Wiki page

Technical information

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.BETA.INV

BETADIST

Returns the beta function.

Syntax

BETADIST(Number; Alpha; Beta [; Start [; End [; Cumulative]]])

Number is the value between Start and End at which to evaluate the function.

Alpha is a parameter to the distribution.

Beta is a parameter to the distribution.

Start (optional) is the lower bound for Number.

End (optional) is the upper bound for Number.

Cumulative (optional) can be 0 or False to calculate the probability density function. It can be any other value or True or omitted to calculate the cumulative distribution function.

Example

=BETADIST(0.75;3;4) returns the value 0.96.

BETAINV

Returns the inverse of the cumulative Beta probability density function.

Syntax

BETAINV(Number; Alpha; Beta [; Start [; End]])

Number is the probability associated with the Beta distribution for the given arguments Alpha and Beta.

Alpha is a strictly positive parameter of the Beta distribution.

Beta is a strictly positive parameter of the Beta distribution.

Start (optional) is the lower bound of the output range of the function. If omitted, the default value is 0.

End (optional) is the upper bound of the output range of the function. If omitted, the default value is 1.

Example

=BETAINV(0.5;5;10) returns the value 0.3257511553.

BETAINV Wiki page

BINOM.DIST

Returns the individual term binomial distribution probability.

Syntax

BINOM.DIST(X; Trials; SP; C)

X is the number of successes in a set of trials.

Trials is the number of independent trials.

SP is the probability of success on each trial.

C = 0 calculates the probability of a single event and C = 1 calculates the cumulative probability.

Example

=BINOM.DIST(A1;12;0.5;0) shows (if the values 0 to 12 are entered in A1) the probabilities for 12 flips of a coin that Heads will come up exactly the number of times entered in A1.

=BINOM.DIST(A1;12;0.5;1) shows the cumulative probabilities for the same series. For example, if A1 = 4, the cumulative probability of the series is 0, 1, 2, 3 or 4 times Heads (non-exclusive OR).

Technical information

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.BINOM.DIST

BINOM.INV

Returns the smallest value for which the cumulative binomial distribution is greater than or equal to a criterion value.

Syntax

BINOM.INV(Trials; SP; Alpha)

Trials The total number of trials.

SP is the probability of success on each trial.

Alpha The border probability that is attained or exceeded.

Example

=BINOM.INV(8;0.6;0.9) returns 7, the smallest value for which the cumulative binomial distribution is greater than or equal to a criterion value.

Technical information

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.BINOM.INV

BINOMDIST

Returns the individual term binomial distribution probability.

Syntax

BINOMDIST(X; Trials; SP; C)

X is the number of successes in a set of trials.

Trials is the number of independent trials.

SP is the probability of success on each trial.

C = 0 calculates the probability of a single event and C = 1 calculates the cumulative probability.

Example

=BINOMDIST(A1;12;0.5;0) shows (if the values 0 to 12 are entered in A1) the probabilities for 12 flips of a coin that Heads will come up exactly the number of times entered in A1.

=BINOMDIST(A1;12;0.5;1) shows the cumulative probabilities for the same series. For example, if A1 = 4, the cumulative probability of the series is 0, 1, 2, 3 or 4 times Heads (non-exclusive OR).

CHIDIST

Returns the probability value from the indicated chi-square that a hypothesis is confirmed. CHIDIST compares the chi-square value to be given for a random sample that is calculated from the sum of (observed value-expected value)^2/expected value for all values with the theoretical chi-square distribution and determines from this the probability of error for the hypothesis to be tested.

The probability determined by CHIDIST can also be determined by CHITEST.

Syntax

CHIDIST(Number; DegreesFreedom)

Number is the chi-square value of the random sample used to determine the error probability.

DegreesFreedom are the degrees of freedom of the experiment.

Example

=CHIDIST(13.27; 5) equals 0.02.

If the chi-square value of the random sample is 13.27 and if the experiment has 5 degrees of freedom, then the hypothesis is assured with a probability of error of 2%.

CHIINV

Returns the inverse of the one-tailed probability of the chi-square distribution.

Syntax

CHIINV(Number; DegreesFreedom)

Number is the value of the error probability.

DegreesFreedom is the degrees of freedom of the experiment.

Example

A die is thrown 1020 times. The numbers on the die 1 through 6 come up 195, 151, 148, 189, 183 and 154 times respectively (observation values). The hypothesis that the die is not fixed is to be tested.

The chi-square distribution of the random sample is determined by the formula given above. Since the expected value for a given number on the die for n throws is n times 1/6, thus 1020/6 = 170, the formula returns a chi-square value of 13.27.

If the (observed) chi-square is greater than or equal to the (theoretical) chi-square CHIINV, the hypothesis will be discarded, since the deviation between theory and experiment is too great. If the observed chi-square is less that CHIINV, the hypothesis is confirmed with the indicated probability of error.

=CHIINV(0.05;5) returns 11.07.

=CHIINV(0.02;5) returns 13.39.

If the probability of error is 5%, the die is not true. If the probability of error is 2%, there is no reason to believe it is fixed.

CHISQ.DIST

Returns the probability density function or the cumulative distribution function for the chi-square distribution.

Syntax

CHISQ.DIST(Number; DegreesFreedom; Cumulative)

Number is the chi-square value of the random sample used to determine the error probability.

DegreesFreedom are the degrees of freedom of the experiment.

Cumulative can be 0 or False to calculate the probability density function. It can be any other value or True to calculate the cumulative distribution function.

Example

=CHISQ.DIST(3; 2; 0) equals 0.1115650801, the probability density function with 2 degrees of freedom, at x = 3.

=CHISQ.DIST(3; 2; 1) equals 0.7768698399, the cumulative chi-square distribution with 2 degrees of freedom, at the value x = 3.

Technical information

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.CHISQ.DIST

CHISQ.DIST.RT

Returns the probability value from the indicated chi-square that a hypothesis is confirmed. CHISQ.DIST.RT compares the chi-square value to be given for a random sample that is calculated from the sum of (observed value-expected value)^2/expected value for all values with the theoretical chi-square distribution and determines from this the probability of error for the hypothesis to be tested.

The probability determined by CHISQ.DIST.RT can also be determined by CHITEST.

Syntax

CHISQ.DIST.RT(Number; DegreesFreedom)

Number is the chi-square value of the random sample used to determine the error probability.

DegreesFreedom are the degrees of freedom of the experiment.

Example

=CHISQ.DIST.RT(13.27; 5) equals 0.0209757694.

If the chi-square value of the random sample is 13.27 and if the experiment has 5 degrees of freedom, then the hypothesis is assured with a probability of error of 2%.

Technical information

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.CHISQ.DIST.RT

CHISQ.INV

Returns the inverse of the left-tailed probability of the chi-squared distribution.

Syntax

CHISQ.INV(Probability; DegreesFreedom)

Probability is the probability value for which the inverse of the chi-square distribution is to be calculated.

Degrees Of Freedom is the degrees of freedom for the chi-square function.

Example

=CHISQ.INV(0,5;1) returns 0.4549364231.

Technical information

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.CHISQ.INV

CHISQ.INV.RT

Returns the inverse of the one-tailed probability of the chi-squared distribution.

Syntax

CHISQ.INV.RT(Number; DegreesFreedom)

Number is the value of the error probability.

DegreesFreedom is the degrees of freedom of the experiment.

Example

A die is thrown 1020 times. The numbers on the die 1 through 6 come up 195, 151, 148, 189, 183 and 154 times (observation values). The hypothesis that the die is not fixed is to be tested.

=CHISQ.INV.RT(0.05;5) returns 11.0704976935.

=CHISQ.INV.RT(0.02;5) returns 13.388222599.

If the probability of error is 5%, the die is not true. If the probability of error is 2%, there is no reason to believe it is fixed.

Technical information

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.CHISQ.INV.RT

CHISQ.TEST

Returns the probability of a deviance from a random distribution of two test series based on the chi-squared test for independence. CHISQ.TEST returns the chi-squared distribution of the data.

The probability determined by CHISQ.TEST can also be determined with CHISQ.DIST, in which case the Chi-square of the random sample must then be passed as a parameter instead of the data row.

Syntax

CHISQ.TEST(DataB; DataE)

DataB is the array of the observations.

DataE is the range of the expected values.

Example

| | Data-B (observed) | Data-E (expected) | | | --------------------- | ------------------ | --- | | 1 | 195 | 170 | | 2 | 151 | 170 | | 3 | 148 | 170 | | 4 | 189 | 170 | | 5 | 183 | 170 | | 6 | 154 | 170 |

=CHISQ.TEST(A1:A6;B1:B6) equals 0.0209708029. This is the probability which suffices the observed data of the theoretical chi-square distribution.

Technical information

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.CHISQ.TEST

CHISQDIST

Returns the value of the probability density function or the cumulative distribution function for the chi-square distribution.

Syntax

CHISQDIST(Number; Degrees Of Freedom [; Cumulative])

Number is the number for which the function is to be calculated.

Degrees Of Freedom is the degrees of freedom for the chi-square function.

Cumulative (optional): 0 or False calculates the probability density function. Other values or True or omitted calculates the cumulative distribution function.

CHISQINV

Returns the inverse of CHISQDIST.

Syntax

CHISQINV(Probability; Degrees of Freedom)

Probability is the probability value for which the inverse of the chi-square distribution is to be calculated.

Degrees Of Freedom is the degrees of freedom for the chi-square function.

CHITEST

Returns the probability of a deviance from a random distribution of two test series based on the chi-square test for independence. CHITEST returns the chi-square distribution of the data.

The probability determined by CHITEST can also be determined with CHIDIST, in which case the chi-square of the random sample must then be passed as a parameter instead of the data row.

Syntax

CHITEST(DataB; DataE)

DataB is the array of the observations.

DataE is the range of the expected values.

Example

=CHITEST(A1:A6;B1:B6) equals 0.02. This is the probability which suffices the observed data of the theoretical chi-square distribution.

COUNT

Counts how many numbers are in the list of arguments. Text entries are ignored.

Syntax

COUNT(Number 1 [; Number 2 [; … [; Number 255]]])

Number 1, Number 2, … , Number 255 are numbers, references to cells or to cell ranges of numbers.

Example

The entries 2, 4, 6 and eight in the Value 1 ... 4 fields are to be counted.

=COUNT(2;4;6;"eight") = 3. The count of numbers is therefore 3.

COUNTA

Counts how many values are in the list of arguments. Text entries are also counted, even when they contain an empty string of length 0. If an argument is an array or reference, empty cells within the array or reference are ignored.

Syntax

COUNTA(Number 1 [; Number 2 [; … [; Number 255]]])

Number 1, Number 2, … , Number 255 are numbers, references to cells or to cell ranges of numbers.

Example

The entries 2, 4, 6 and eight in the Value 1 ... 4 fields are to be counted.

=COUNTA(2;4;6;"eight") = 4. The count of values is therefore 4.

COUNTBLANK

Returns the number of empty cells.

Syntax

COUNTBLANK(Range)

Returns the number of empty cells in the cell range Range.

Example

=COUNTBLANK(A1:B2) returns 4 if cells A1, A2, B1, and B2 are all empty.

COUNTIF

Returns the number of cells that meet with certain criteria within a cell range.

Syntax

COUNTIF(Range; Criterion)

Range is the range to which the criteria are to be applied.

Criterion: A criterion is a single cell Reference, Number or Text. It is used in comparisons with cell contents.

A reference to an empty cell is interpreted as the numeric value 0.

A matching expression can be:

A Number or Logical value. A matching cell content equals the Number or Logical value.
A value beginning with a comparator (<, <=, =, >, >=, <>).

For =, if the value is empty it matches empty cells.
For <>, if the value is empty it matches non-empty cells.
For <>, if the value is not empty it matches any cell content except the value, including empty cells.
Note: "=0" does not match empty cells.
For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes and the property Search criteria = and <> must apply to whole cells is checked, comparison is against the entire cell contents, if unchecked, comparison is against any subpart of the field that matches the criteria. For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes applies.

Other Text value. If the property Search criteria = and <> must apply to whole cells is true, the comparison is against the entire cell contents, if false, comparison is against any subpart of the field that matches the criteria. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in Tools - Options - Office Calc - Calculate.

Example

A1:A10 is a cell range containing the numbers 2000 to 2009. Cell B1 contains the number 2006. In cell B2, you enter a formula:

=COUNTIF(A1:A10;2006) - this returns 1.

=COUNTIF(A1:A10;B1) - this returns 1.

=COUNTIF(A1:A10;">=2006") - this returns 4.

=COUNTIF(A1:A10;"<"&B1) - when B1 contains 2006, this returns 6.

=COUNTIF(A1:A10;C2) where cell C2 contains the text >2006 counts the number of cells in the range A1:A10 which are >2006.

To count only negative numbers: =COUNTIF(A1:A10;"<0")

EXPON.DIST

Returns the exponential distribution.

Syntax

EXPON.DIST(Number; Lambda; C)

Number is the value of the function.

Lambda is the parameter value.

C is a logical value that determines the form of the function. C = 0 calculates the density function, and C = 1 calculates the distribution.

Example

=EXPON.DIST(3;0.5;1) returns 0.7768698399.

Technical information

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.EXPON.DIST

EXPONDIST

Returns the exponential distribution.

Syntax

EXPONDIST(Number; Lambda; C)

Number is the value of the function.

Lambda is the parameter value.

C is a logical value that determines the form of the function. C = 0 calculates the density function, and C = 1 calculates the distribution.

Example

=EXPONDIST(3;0.5;1) returns 0.78.

INTERCEPT

Calculates the point at which a line will intersect the y-values by using known x-values and y-values.

Syntax

INTERCEPT(DataY; DataX)

DataY is the dependent set of observations or data.

DataX is the independent set of observations or data.

Names, arrays or references containing numbers must be used here. Numbers can also be entered directly.

Example

To calculate the intercept, use cells D3:D9 as the y-values and C3:C9 as the x-values from the example spreadsheet. Input will be as follows:

=INTERCEPT(D3:D9;C3:C9) = 2.15.

RSQ

Returns the square of the Pearson correlation coefficient based on the given values. RSQ (also called the coefficient of determination) is a measure for the accuracy of an adjustment and can be used to produce a regression analysis.

Syntax

RSQ(DataY; DataX)

DataY is an array or range of data points.

DataX is an array or range of data points.

Example

=RSQ(A1:A20;B1:B20) calculates the coefficient of determination for both data sets in columns A and B.

Functions by Category