ScriptForge.Array service
Provides a collection of methods for manipulating and transforming arrays of one dimension (vectors) and arrays of two dimensions (matrices). This includes set operations, sorting, importing from and exporting to text files.
Arrays with more than two dimensions cannot be used with the methods in this service, the only exception being the CountDims method that accepts Arrays with any number of dimensions.
Array items may contain any type of value, including (sub)arrays.
Service invocation
Before using the Array service the ScriptForge library needs to be loaded using:
GlobalScope.BasicLibraries.loadLibrary("ScriptForge")
Loading the library will create the SF-Array object that can be used to call the methods in the Array service.
The following code snippets show the various ways to call methods in the Array service (the Append method is used as an example):
Dim arr : arr = Array(1, 2, 3)
arr = SF-Array.Append(arr, 4)
Dim arr : arr = Array(1, 2, 3)
Dim svc : svc = SF-Array
arr = svc.Append(arr, 4)
Dim arr : arr = Array(1, 2, 3)
Dim svc : svc = CreateScriptService("Array")
arr = svc.Append(arr, 4)
Because Python has built-in list and tuple support, most of the methods in the Array service are available for Basic scripts only. The only exception is ImportFromCSVFile which is supported in both Basic and Python.
The first argument of most methods is the array object to be considered. It is always passed by reference and left unchanged. Methods such as Append, Prepend, etc return a new array object after their execution.
Append
Appends the items listed as arguments to the end of the input array.
Syntax:
svc.Append(array-1d: any[0..*], arg0: any, [arg1: any] ...): any[0..*]
Parameters:
array-1d: The pre-existing array, may be empty.
arg0, arg1, ...: Items that will be appended to array-1d.
Example:
Dim a As Variant
a = SF-Array.Append(Array(1, 2, 3), 4, 5)
' (1, 2, 3, 4, 5)
AppendColumn
Appends a new column to the right side of a two dimensional array. The resulting array has the same lower bounds as the initial two dimensional array.
Syntax:
svc.AppendColumn(array-2d: any[0..*, 0..*], column: any[0..*]): any[0..*, 0..*]
Parameters:
array-2d: The pre-existing array, may be empty. If that array has only one dimension, it is considered as the first column of the resulting two-dimensional array.
column: A 1-dimensional array with as many items as there are rows in array-2d.
Example:
Dim a As Variant, b As variant
a = SF-Array.AppendColumn(Array(1, 2, 3), Array(4, 5, 6))
' ((1, 4), (2, 5), (3, 6))
b = SF-Array.AppendColumn(a, Array(7, 8, 9))
' ((1, 4, 7), (2, 5, 8), (3, 6, 9))
c = SF-Array.AppendColumn(Array(), Array(1, 2, 3))
' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
AppendRow
Append to the bottom of a two dimension array a new row. The resulting array has the same lower bounds as the initial two dimension array.
Syntax:
svc.AppendRow(array-2d: any[0..*, 0..*], row: any[0..*]): any[0..*, 0..*])
Parameters:
array-2d: The pre-existing array, may be empty. If that array has 1 dimension, it is considered as the first row of the resulting 2 dimension array.
row: A 1-dimensional array with as many items as there are columns in array-2d.
Example:
Dim a As Variant, b As variant
a = SF-Array.AppendRow(Array(1, 2, 3), Array(4, 5, 6))
' ((1, 2, 3), (4, 5, 6))
b = SF-Array..AppendRow(Array(), Array(1, 2, 3))
' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
Contains
Check if a one dimension array contains a certain number, text or date. Text comparison can be case-sensitive or not.
Sorted input arrays must be filled homogeneously, meaning all items must be scalars of the same type (Empty and Null items are forbidden).
The result of the method is unpredictable when the array is announced as sorted and is in reality not.
A binary search is done when the array is sorted, otherwise, it is simply scanned from top to bottom and Empty and Null items are ignored.
Syntax:
svc.Contains(array-1d: any[0..*], tofind: any, casesensitive: bool = False, sortorder: str = ""): bool
Parameters:
array-1d: The array to scan.
tofind: A number, a date or a string to find.
casesensitive: Only for string comparisons (Default = False).
sortorder: It can be either "ASC", "DESC" or "" (not sorted). The default value is "".
Example:
Dim a As Variant
a = SF-Array.Contains(Array("A","B","c","D"), "C", SortOrder := "ASC") ' True
SF-Array.Contains(Array("A","B","c","D"), "C", CaseSensitive := True) ' False
ConvertToDictionary
Store the content of a 2-columns array into a ScriptForge.Dictionary object.
The key will be extracted from the first column, the item from the second.
Syntax:
svc.ConvertToDictionary(array-2d: any[0..*, 0..1]): obj
Parameters:
array-2d: Data to be converted into a ScriptForge.Dictionary object.
- The first column must contain exclusively strings with a length greater than zero, in any order. These values will be used as labels in the dictionary.
- The second column contains the data that will be associated to the corresponding label in the dictionary.
Example:
Dim a As Variant, b As Variant
a = SF-Array.AppendColumn(Array("a", "b", "c"), Array(1, 2, 3))
b = SF-Array.ConvertToDictionary(a)
MsgBox b.Item("c") ' 3
Copy
Creates a copy of a 1D or 2D array.
Syntax:
svc.Copy(array-nd: any[0..*]): any[0..*]
svc.Copy(array-nd: any[0..*, 0..*]): any[0..*, 0..*]
Parameters:
array-nd: The 1D or 2D array to be copied.
Example:
A simple assignment of an Array object will copy its reference instead of creating a copy of the object's contents. See the example below:
Dim a as Variant, b as Variant
a = Array(1, 2, 3)
' The assignment below is made by reference
b = a
' Hence changing values in "b" will also change "a"
b(0) = 10
MsgBox a(0) ' 10
By using the Copy method, a copy of the whole Array object is made. In the example below, a and b are different objects and changing values in b will not affect values in a.
Dim a as Variant, b as Variant
a = Array(1, 2, 3)
' Creates a copy of "a" using the "Copy" method
b = SF-Array.Copy(a)
b(0) = 10
MsgBox a(0) ' 1
CountDims
Count the number of dimensions of an array. The result can be greater than two.
If the argument is not an array, returns -1
If the array is not initialised, returns 0.
Syntax:
svc.CountDims(array-nd: any): int
Parameters:
array-nd: The array to examine.
Example:
Dim a(1 To 10, -3 To 12, 5)
MsgBox SF-Array.CountDims(a) ' 3
Difference
Build a set, as a zero-based array, by applying the difference operator on the two input arrays. Resulting items originate from the first array and not from the second.
The resulting array is sorted in ascending order.
Both input arrays must be filled homogeneously, their items must be scalars of the same type. Empty and Null items are forbidden.
Text comparison can be case sensitive or not.
Syntax:
svc.Difference(array1-1d: any[0..*], array2-1d: any[0..*], casesensitive: bool = False): any[0..*]
Parameters:
array1-1d: A 1-dimensional reference array, whose items are examined for removal.
array2-1d: A 1-dimensional array, whose items are subtracted from the first input array.
casesensitive: This argument is only applicable if the arrays are populated with strings (Default = False).
Example:
Dim a As Variant
a = SF-Array.Difference(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
' ("A", "B")
ExportToTextFile
Write all items of the array sequentially to a text file. If the file exists already, it will be overwritten without warning.
Syntax:
svc.ExportToTextFile(array-1d: any[0..*], filename: str, [encoding: str]): bool
Parameters:
array-1d: The array to export. It must contain only strings.
filename: The name of the text file where the data will be written to. The name must be expressed according to the current FileNaming property of the SF-FileSystem service.
encoding: The character set that should be used. Use one of the names listed in IANA character sets. Note that Office may not implement all existing character sets (Default is "UTF-8").
Example:
SF-Array.ExportToTextFile(Array("A","B","C","D"), "C:\Temp\A short file.txt")
ExtractColumn
Extract from a two dimension array a specific column as a new array.
Its lower LBound and upper UBound boundaries are identical to that of the first dimension of the input array.
Syntax:
svc.ExtractColumn(array-2d: any[0..*, 0..*], columnindex: int): any[0..*, 0..*]
Parameters:
array-2d: The array from which to extract.
columnindex: The column number to extract - must be in the interval [LBound, UBound].
Example:
'Creates a 3x3 matrix: |1, 2, 3|
' |4, 5, 6|
' |7, 8, 9|
Dim mat as Variant, col as Variant
mat = SF-Array.AppendRow(Array(), Array(1, 2, 3))
mat = SF-Array.AppendRow(mat, Array(4, 5, 6))
mat = SF-Array.AppendRow(mat, Array(7, 8, 9))
'Extracts the third column: |3, 6, 9|
col = SF-Array.ExtractColumn(mat, 2)
ExtractRow
Extract from a two dimension array a specific row as a new array.
Its lower LBound and upper UBound boundaries are identical to that of the second dimension of the input array.
Syntax:
svc.ExtractRow(array-2d: any[0..*, 0..*], rowindex: int): any[0..*, 0..*]
Parameters:
array-2d: The array from which to extract.
rowindex: The row number to extract - must be in the interval [LBound, UBound].
Example:
'Creates a 3x3 matrix: |1, 2, 3|
' |4, 5, 6|
' |7, 8, 9|
Dim mat as Variant, row as Variant
mat = SF-Array.AppendRow(Array(), Array(1, 2, 3))
mat = SF-Array.AppendRow(mat, Array(4, 5, 6))
mat = SF-Array.AppendRow(mat, Array(7, 8, 9))
'Extracts the first row: |1, 2, 3|
row = SF-Array.ExtractRow(mat, 0)
Flatten
Stack all single items of an array and all items in its subarrays into one new array without subarrays. Empty subarrays are ignored and subarrays with a number of dimensions greater than one are not flattened.
Syntax:
svc.Flatten(array-1d: any[0..*]): any[0..*]
Parameters:
array-1d: The pre-existing array, may be empty.
Example:
Dim a As Variant
a = SF-Array.Flatten(Array(Array(1, 2, 3), 4, 5))
' (1, 2, 3, 4, 5)
You can use the Flatten method along with other methods such as Append or Prepend to concatenate a set of 1D arrays into a single 1D array.
Example:
Next is an example of how the methods Flatten and Append can be combined to concatenate three arrays.
'Creates three arrays for this example
Dim a as Variant, b as Variant, c as Variant
a = Array(1, 2, 3)
b = Array(4, 5)
c = Array(6, 7, 8, 9)
'Concatenates the three arrays into a single 1D array
Dim arr as Variant
arr = SF-Array.Flatten(SF-Array.Append(a, b, c))
'(1, 2, 3, 4, 5, 6, 7, 8, 9)
ImportFromCSVFile
Import the data contained in a comma-separated values (CSV) file. The comma may be replaced by any character.
The applicable CSV format is described in IETF Common Format and MIME Type for CSV Files.
Each line in the file contains a full record (line splitting is not allowed).
However sequences like \n, \t, ... are left unchanged. Use SF-String.Unescape() method to manage them.
The method returns a two dimension array whose rows correspond to a single record read in the file and whose columns correspond to a field of the record. No check is made about the coherence of the field types across columns. A best guess will be made to identify numeric and date types.
If a line contains less or more fields than the first line in the file, an exception will be raised. Empty lines however are simply ignored. If the size of the file exceeds the number of items limit (see inside the code), a warning is raised and the array is truncated.
Syntax:
svc.ImportFromCSVFile(filename: str, delimiter: str = ',', dateformat: str = ''): any[0..*]
Parameters:
filename: The name of the text file containing the data. The name must be expressed according to the current FileNaming property of the SF-FileSystem service.
delimiter: A single character, usually, a comma, a semicolon or a TAB character (Default = ",").
dateformat: A special mechanism handles dates when dateformat is either "YYYY-MM-DD", "DD-MM-YYYY" or "MM-DD-YYYY". The dash (-) may be replaced by a dot (.), a slash (/) or a space. Other date formats will be ignored. Dates defaulting to an empty string "" are considered as normal text.
Example:
Consider the CSV file "myFile.csv" with the following contents:
Name,DateOfBirth,Address,City
Anna,2002/03/31,"Rue de l'église, 21",Toulouse
Fred,1998/05/04,"Rue Albert Einstein, 113A",Carcassonne
The examples below in Basic and Python read the contents of the CSV file into an Array object.
In Basic
Dim arr As Variant
arr = SF-Array.ImportFromCSVFile("C:\Temp\myFile.csv", DateFormat := "YYYY/MM/DD")
MsgBox arr(0, 3) ' City
MsgBox arr(1, 2) ' Rue de l'église, 21
MsgBox arr(1, 3) ' Toulouse
In Python
from scriptforge import CreateScriptService
svc = CreateScriptService("Array")
bas = CreateScriptService("Basic")
arr = svc.ImportFromCSVFile(r"C:\Temp\myFile.csv", dateformat = "YYYY/MM/DD")
bas.MsgBox(arr[0][3]) # City
bas.MsgBox(arr[1][2]) # Rue de l'église, 21
bas.MsgBox(arr[1][3]) # Toulouse
IndexOf
Look in a one dimension array for a number, a string or a date. Text comparison can be case-sensitive or not.
If the array is sorted it must be filled homogeneously, which means that all items must be scalars of the same type (Empty and Null items are forbidden).
The result of the method is unpredictable when the array is announced as sorted and actually is not.
A binary search is performed on sorted arrays. Otherwise, arrays are simply scanned from top to bottom and Empty and Null items are ignored.
The method returns LBound(input array) - 1 if the search was not successful.
Syntax:
svc.IndexOf(array-1d: any[0..*], tofind: any, casesensitive: bool = False, sortorder: str = ''): int
Parameters:
array-1d: The array to scan.
tofind: A number, a date or a string to find.
casesensitive: Only for string comparisons (Default = False).
sortorder: It can be either "ASC", "DESC" or "" (not sorted). The default value is "".
Example:
MsgBox SF-Array.IndexOf(Array("A","B","c","D"), "C", SortOrder := "ASC") ' 2
MsgBox SF-Array.IndexOf(Array("A","B","c","D"), "C", CaseSensitive := True) ' -1
Insert
Insert before a given index of the input array the items listed as arguments.
Arguments are inserted blindly. Each of them might be either a scalar of any type or a subarray.
Syntax:
svc.Insert(array-1d: any[0..*], before: int, arg0: any, [arg1: any] ...): any[0..*]
Parameters:
array-1d: The pre-existing array, may be empty.
before: The index before which to insert; must be in the interval [LBound, UBound + 1].
arg0, arg1, ...: Items that will be inserted into array-1d.
Example:
Dim a As Variant
a = SF-Array.Insert(Array(1, 2, 3), 2, "a", "b")
' (1, 2, "a", "b", 3)
InsertSorted
Inserts into a sorted array a new item on its place.
The array must be filled homogeneously, meaning that all items must be scalars of the same type.
Empty and Null items are forbidden.
Syntax:
svc.InsertSorted(array-1d: any[0..*], item: any, sortorder: str = 'ASC', casesensitive: bool = False): any[0..*]
Parameters:
array-1d: The array into which the value will be inserted.
item: The scalar value to insert, of the same type as the existing array items.
sortorder: It can be either "ASC" (default) or "DESC".
casesensitive: Only for string comparisons (Default = False).
Example:
Dim a As Variant
a = SF-Array.InsertSorted(Array("A", "C", "a", "b"), "B", CaseSensitive := True)
' ("A", "B", "C", "a", "b")
Intersection
Build a set, as a zero-based array, by applying the intersection set operator on the two input arrays. Resulting items are contained in both arrays.
The resulting array is sorted in ascending order.
Both input arrays must be filled homogeneously, in other words all items must be scalars of the same type. Empty and Null items are forbidden.
Text comparison can be case sensitive or not.
Syntax:
svc.Intersection(array1-1d: any[0..*], array2-1d: any[0..*], casesensitive: bool = False): any[0..*]
Parameters:
array1-1d: The first input array.
array2-1d: The second input array.
casesensitive: Applies to arrays populated with text items (Default = False).
Example:
Dim a As Variant
a = SF-Array.Intersection(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
' ("C", "b")
Join2D
Join a two-dimensional array with two delimiters, one for the columns, one for the rows.
Syntax:
svc.Join2D(array-2d: any [0..*, 0..*], [columndelimiter: str], [rowdelimiter: str], [quote: str]): str
Parameters:
array-2d: Each item must be either text, a number, a date or a boolean.
Dates are transformed into the YYYY-MM-DD hh:mm:ss format.
Invalid items are replaced by a zero-length string.
columndelimiter: Delimits each column (default = Tab/Chr(9)).
rowdelimiter: Delimits each row (default = LineFeed/Chr(10))
quote: If True, protect strings with double quotes. The default is False.
Example:
' arr = | 1, 2, "A", [2020-02-29], 51, 2, "A", [2020-02-29], 5 |
' | 6, 7, "this is a string", 9, 106, 7, "this is a string", 9, 10 |
Dim arr as Variant : arr = Array()
arr = SF-Array.AppendRow(arr, Array(1, 2, "A", [2020-02-29], 51, 2, "A", [2020-02-29], 5))
arr = SF-Array.AppendRow(arr, Array(6, 7, "this is a string", 9, 106, 7, "this is a string", 9, 10))
Dim arrText as String
arrText = SF-Array.Join2D(arr, ",", "/", False)
' 1,2,A,,51,2,A,,5/6,7,this is a string,9,106,7,this is a string,9,10
Prepend
Prepend at the beginning of the input array the items listed as arguments.
Syntax:
svc.Prepend(array-1d: any[0..*], arg0: any, [arg1: any] ...): any[0..*]
Parameters:
array-1d: The pre-existing array, may be empty.
arg0, arg1, ...: A list of items to prepend to array-1d.
Example:
Dim a As Variant
a = SF-Array.Prepend(Array(1, 2, 3), 4, 5)
' (4, 5, 1, 2, 3)
PrependColumn
Prepend to the left side of a two dimension array a new column. The resulting array has the same lower boundaries as the initial two dimension array.
Syntax:
svc.PrependColumn(array-2d: any[0..*, 0..*], column: any[0..*]): any[0..*, 0..*]
Parameters:
array-2d: The pre-existing array, may be empty. If that array has 1 dimension, it is considered as the last column of the resulting 2 dimension array.
column: A 1-dimensional array with as many items as there are rows in array-2d.
Example:
Dim a As Variant, b As variant
a = SF-Array.PrependColumn(Array(1, 2, 3), Array(4, 5, 6))
' ((4, 1), (5, 2), (6, 3))
b = SF-Array.PrependColumn(Array(), Array(1, 2, 3))
' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
PrependRow
Prepend a new row at the beginning of a 2-dimensional array. The resulting array has the same lower boundaries as the initial 2-dimensional array.
Syntax:
svc.PrependRow(array-2d: any[0..*, 0..*], row: any[0..*]): any[0..*, 0..*]
Parameters:
array-2d: The pre-existing array, may be empty. If that array has 1 dimension, it is considered as the last row of the resulting 2-dimensional array.
row: A 1-dimensional array containing as many items as there are columns in array-2d.
Example:
Dim a As Variant, b As variant
a = SF-Array.PrependRow(Array(1, 2, 3), Array(4, 5, 6))
' ((4, 5, 6), (1, 2, 3))
b = SF-Array.PrependRow(Array(), Array(1, 2, 3))
' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
RangeInit
Initialise a new zero-based array with numeric values.
Syntax:
svc.RangeInit(from: num, upto: num, [bystep: num]): num[0..*]
Parameters:
from: Value of the first item.
upto: The last item should not exceed UpTo.
bystep: The difference between two successive items (Default = 1).
Example:
Dim a As Variant
a = SF-Array.RangeInit(10, 1, -1)
' (10, 9, 8, 7, 6, 5, 4, 3, 2, 1)
Reverse
Return the reversed one dimension input array.
Syntax:
svc.Reverse(array-1d: any[0..*]): any[0..*]
Parameters:
array-1d: The array to reverse.
Example:
Dim a As Variant
a = SF-Array.Reverse(Array("a", 2, 3, 4))
' (4, 3, 2, "a")
Shuffle
Returns a random permutation of a one-dimensional array.
Syntax:
svc.Shuffle(array-1d: any[0..*]): any[0..*]
Parameters:
array-1d: The array to shuffle.
Example:
Dim a As Variant
a = SF-Array.Shuffle(Array(1, 2, 3, 4))
' Array "a" is now in random order, f.i. (2, 3, 1, 4)
Slice
Returns a subset of a one-dimensional array.
Syntax:
svc.Slice(array-1d: any[0..*], from: int, [upto: int]): any[0..*]
Parameters:
array-1d: The array to slice.
from: The lower index in array-1d of the subarray to extract (from included)
upto: The upper index in array-1d of the subarray to extract (upto included). The default value is the upper bound of array-1d. If upto < from then the returned array is empty.
Example:
Dim a As Variant
a = SF-Array.Slice(Array(1, 2, 3, 4, 5), 1, 3) ' (2, 3, 4)
Sort
Sort a one dimension array in ascending or descending order. Text comparisons can be case-sensitive or not.
The array must be filled homogeneously, which means that items must be scalars of the same type.
Empty and Null items are allowed. Conventionally Empty < Null < any other scalar value.
Syntax:
svc.Sort(array-1d: any[0..*], sortorder: str, casesensitive: bool = False): any[0..*]
Parameters:
array-1d: The array to sort.
sortorder: It can be either "ASC" (default) or "DESC".
casesensitive: Only for string comparisons (Default = False).
Example:
Dim a As Variant
a = SF-Array.Sort(Array("a", "A", "b", "B", "C"), CaseSensitive := True)
' ("A", "B", "C", "a", "b")
SortColumns
Return a permutation of the columns of a two dimension array, sorted on the values of a given row.
The row must be filled homogeneously, which means that all items must be scalars of the same type.
Empty and Null items are allowed. Conventionally Empty < Null < any other scalar value.
Syntax:
svc.SortColumns(array-2d: any[0..*, 0..*], rowindex: int, sortorder: str, casesensitive: bool = False): any[0..*, 0..*]
Parameters:
array-2d: The 2-dimensional array to sort.
rowindex: The index of the row that will be used as reference to sort the columns.
sortorder: It can be either "ASC" (default) or "DESC".
casesensitive: Only for string comparisons (Default = False).
Example:
' arr = | 5, 7, 3 |
' | 1, 9, 5 |
' | 6, 1, 8 |
Dim arr as Variant : arr = Array(5, 7, 3)
arr = SF-Array.AppendRow(arr, Array(1, 9, 5))
arr = SF-Array.AppendRow(arr, Array(6, 1, 8))
arr = SF-Array.SortColumns(arr, 2, "ASC")
' arr = | 7, 5, 3 |
' | 9, 1, 5 |
' | 1, 6, 8 |
SortRows
Return a permutation of the rows of a two dimension array, sorted on the values of a given column.
The column must be filled homogeneously, therefore all items must be scalars of the same type.
Empty and Null items are allowed. Conventionally Empty < Null < any other scalar value.
Syntax:
svc.SortRows(array-2d: any[0..*, 0..*], columnindex: int, sortorder: str, casesensitive: bool = False): any[0..*, 0..*]
Parameters:
array-2d: The array to sort.
columnindex: The index of the column that will be used as reference to sort the rows.
sortorder: It can be either "ASC" (default) or "DESC".
casesensitive: Only for string comparisons (Default = False).
Example:
' arr = | 5, 7, 3 |
' | 1, 9, 5 |
' | 6, 1, 8 |
Dim arr as Variant : arr = Array(5, 7, 3)
arr = SF-Array.AppendRow(arr, Array(1, 9, 5))
arr = SF-Array.AppendRow(arr, Array(6, 1, 8))
arr = SF-Array.SortRows(arr, 0, "ASC")
' arr = | 1, 9, 5 |
' | 5, 7, 3 |
' | 6, 1, 8 |
Transpose
Swaps rows and columns in a two-dimensional array.
Syntax:
svc.Transpose(array-2d: any[0..*, 0..*]): any[0..*, 0..*]
Parameters:
array-2d: The 2-dimensional array to transpose.
Example:
' arr1 = | 1, 2 |
' | 3, 4 |
' | 5, 6 |
arr1 = Array(1, 2)
arr1 = SF-Array.AppendRow(arr1, Array(3, 4))
arr1 = SF-Array.AppendRow(arr1, Array(5, 6))
arr2 = SF-Array.Transpose(arr1)
' arr2 = | 1, 3, 5 |
' | 2, 4, 6 |
MsgBox arr2(0, 2) ' 5
TrimArray
Remove from a one dimension array all Null, Empty and zero-length entries.
String items are trimmed with Office Basic Trim() function.
Syntax:
svc.TrimArray(array-1d: any[0..*]): any[0..*]
Parameters:
array-1d: The array to trim.
Example:
Dim a As Variant
a = SF-Array.TrimArray(Array("A", "B", Null, " D "))
' ("A", "B", "D")
Union
Builds a set, as a zero-based array, by applying the union operator on the two input arrays. Resulting items originate from any of both arrays.
The resulting array is sorted in ascending order.
Both input arrays must be filled homogeneously, their items must be scalars of the same type. Empty and Null items are forbidden.
Text comparison can be case sensitive or not.
Syntax:
svc.Union(array1-1d: any[0..*], array2-1d: any[0..*], casesensitive: bool = False): any[0..*]
Parameters:
array1-1d: The first input array.
array2-1d: The second input array.
casesensitive: Applicable only if the arrays are populated with strings (Default = False).
Example:
Dim a As Variant
a = SF-Array.Union(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
' ("A", "B", "C", "Z", "b")
Unique
Build a set of unique values derived from the input array.
The input array must be filled homogeneously, its items must be scalars of the same type. Empty and Null items are forbidden.
Text comparison can be case sensitive or not.
Syntax:
svc.Unique(array-1d: any[0..*], casesensitive: bool = False): any[0..*]
Parameters:
array-1d: The input array.
casesensitive: Applicable only if the array is populated with strings (Default = False).
Example:
Dim a As Variant
a = SF-Array.Unique(Array("A", "C", "A", "b", "B"), CaseSensitive := True)
' ("A", "B", "C", "b")
All ScriptForge Basic routines or identifiers that are prefixed with an underscore character "-" are reserved for internal use. They are not meant be used in Basic macros or Python scripts.